advent04/Main.hs

   1 -- Writeup at https://work.njae.me.uk/2022/12/04/advent-of-code-2022-day-4/
   2
   3 import AoC
   4 import Data.Text (Text)
   5 import qualified Data.Text.IO as TIO
   6 import Data.Attoparsec.Text hiding (Result)
   7 -- import Control.Applicative
   8
   9 data Assignment = Assignment Int Int deriving (Show, Eq)
  10 type Pair = (Assignment, Assignment)
  11
  12 main :: IO ()
  13 main =
  14   do  dataFileName <- getDataFileName
  15       text <- TIO.readFile dataFileName
  16       let pairs = successfulParse text
  17       print $ part1 pairs
  18       print $ part2 pairs
  19
  20 part1 :: [Pair] -> Int
  21 part1 = length . (filter hasContainment)
  22
  23 part2 :: [Pair] -> Int
  24 part2 = length . (filter overlaps)
  25
  26 hasContainment, disjoint, overlaps :: Pair -> Bool
  27 hasContainment (assignment1, assignment2) =
  28   (assignment1 `contains` assignment2) || (assignment2 `contains` assignment1)
  29
  30 disjoint (assignment1, assignment2) =
  31   (assignment1 `before` assignment2) || (assignment2 `before` assignment1)
  32
  33 overlaps = not . disjoint
  34
  35 contains, before :: Assignment -> Assignment -> Bool
  36 contains (Assignment lower1 upper1) (Assignment lower2 upper2) =
  37   (lower1 <= lower2) && (upper1 >= upper2)
  38
  39 before (Assignment _lower1 upper1) (Assignment lower2 _upper2) =
  40   (upper1 < lower2)
  41
  42 -- Parse the input file
  43
  44 pairsP :: Parser [Pair]
  45 pairP :: Parser Pair
  46 assignmentP :: Parser Assignment
  47
  48 pairsP = pairP `sepBy` endOfLine
  49 pairP = (,) <$> assignmentP <* "," <*> assignmentP
  50
  51 assignmentP = Assignment <$> decimal <* "-" <*> decimal
  52
  53 successfulParse :: Text -> [Pair]
  54 successfulParse input =
  55   case parseOnly pairsP input of
  56     Left  _err -> [] -- TIO.putStr $ T.pack $ parseErrorPretty err
  57     Right pairs -> pairs